【IRIS/Cache】グローバルざっくり解説#0　グローバルの基本操作

k ^Sample
s nm = "ビル"

set ^Sample("東京都")="首都"
SET ^Sample("東京都","新宿区")="県庁所在地"
s ^Sample("東京都","新宿区","西新宿",2,8,1)="東京都庁"

// 条件付きset文　ビル=true, 都庁=false
s:(nm="ビル") ^Sample("東京都","新宿区","西新宿",6,10,1)="日土地西新宿ビル"
s:(nm="都庁") ^Sample("東京都","新宿区","西新宿",6,10,1,"15階")="インターシステムズジャパン"

zw ^Sample
// ^Sample("東京都")="首都"
// ^Sample("東京都","新宿区")="県庁所在地"
// ^Sample("東京都","新宿区","西新宿",2,8,1)="東京都庁"
// ^Sample("東京都","新宿区","西新宿",6,10,1)="日土地西新宿ビル"

k ^Sample

// 複数の変数/グローバルに対し、同時に値を代入する
s (code, name, key, mode) = ""
s ( ^Sample(1), ^Sample(2), ^Sample(3) ) = "テストデータ"
zw ^Sample
// ^Sample(1)="テストデータ"
// ^Sample(2)="テストデータ"
// ^Sample(3)="テストデータ"

k ^Sample
s ^Sample("てすと")="てすと"
s ^Sample("test")="テスト"
s ^Sample(001)="1として認識する"
s ^Sample("001")="001として認識する"
s ^Sample(10)=10

zw ^Sample
// ^Sample(1)="1として認識する"
// ^Sample(10)=10
// ^Sample("001")="001として認識する"
// ^Sample("test")="テスト"
// ^Sample("てすと")="てすと"

k ^Sample
s ^Sample("東京都")="首都"
s ^Sample("東京都","新宿区")="県庁所在地"

//-------------------------------------------------
// 直接取得
w ^Sample("東京都")
// 首都

//-------------------------------------------------
// $get
w $g(^Sample("東京都"))
// 首都
w $g(^Sample("埼玉"), "初期値") // グローバルが無いときは初期値が返る
// 初期値
w $g(^Sample("千葉")) // 省略するとnullが返る
// [null]


//-------------------------------------------------
// $data
s val = $d(^Sample("東京都","新宿区"), dt) // 変数「dt」にデータが格納される
w dt
// 県庁所在地

//-------------------------------------------------
// $order
s key = $o(^Sample("東京都", ""), 1, dt) // 変数「dt」にデータが格納される
w dt
// 県庁所在地

k ^Sample
s ^Sample("東京都")="首都"
s ^Sample("東京都","新宿区")="県庁所在地"
s ^Sample("埼玉県")="さいたま市"
s ^Sample("千葉県", "千葉市")="県庁所在地"

w $d(^Sample("神奈川県")) // データなし
// 0
w $d(^Sample("埼玉県")) // データあり
// 1
w $d(^Sample("千葉県")) // 下位ノードあり
// 10
w $d(^Sample("東京都")) // データ・下位ノードあり
// 11


//-------------------------------------------------
// データ取得
k dt
s flg = $d(^Sample("神奈川県"), dt) // グローバルが無いと、dtは何も変化がない
w dt
// <UNDEFINED> *dt

k dt
s flg = $d(^Sample("埼玉県"), dt) // グローバルが有ると、dtにデータが格納される
w dt
// さいたま市


//-------------------------------------------------
// bool値で返す方法２つ

// 1. グローバルの存在有無をbool値で返す
w $d(^Sample("神奈川県"))#10
// 0
w $d(^Sample("埼玉県"))#10
// 1
w $d(^Sample("千葉県"))#10
// 0
w $d(^Sample("東京都"))#10
// 1

// 2. 下位ノードの存在をbool値で返す
w $d(^Sample("神奈川県"))\10
// 0
w $d(^Sample("埼玉県"))\10
// 0
w $d(^Sample("千葉県"))\10
// 1
w $d(^Sample("東京都"))\10
// 1

makeData	;
	k ^||sample
	f pos1=1:1:5 {
		s ^||sample(pos1) = "第一ノード("_pos1_")"
		
		f pos2=1:1:($r(10)+1) {
			s ^||sample(pos1, pos2) = "第二ノード("_pos2_")"
			
			f pos3=1:1:($r(5)+1) {
				s ^||sample(pos1, pos2, pos3) = "第三ノード("_pos3_")"
			}
		}
	}
d makeData
zw ^||sample

// 先ずは動作確認
w $o(^||sample("")) // 第２, ３引数は省略可
// 1
w $o(^||sample(""),-1)
// 5
w $o(^||sample(5))
// [null]
w $o(^||sample(1),-1)
// [null]

// データ取得
s key = $o(^||sample(1),1,data)
w data
// 第一ノード(2)
s key = $o(^||sample(5),-1,data)
w data
// 第一ノード(4)

// グローバルが無いと、変数「data」は何も操作されない
k data
s key = $o(^||sample(5),1,data)
w data
// <UNDEFINED> *data

// $orderの第2, 3引数は、必要に応じて省略可能です
loopData	;
	s (key1, key2, key3) = ""
	f { s key1 = $o(^||sample(key1),1,data1) q:key1=""
		f { s key2 = $o(^||sample(key1,key2),1,data2) q:key2=""
			f { s key3 = $o(^||sample(key1,key2,key3),1,data3) q:key3=""
				w !,data1,",",data2,",",data3
			}
		}
	}
d loopData

// 先ずは動作確認
w $q(^||sample("")) // 第２, ３引数は省略可
// ^||sample(1)
w $q(^||sample(""),-1)
// ^||sample(5,2,3)    // ★ $orderと異なる点
w $q(^||sample(5,2,3)) // ★ $orderと異なる点
// [null]
w $q(^||sample(1),-1)
// [null]

// データ取得
s key = $q(^||sample(1),1,data)
w data
// 第二ノード(1) ★ $orderと異なる点
s key = $q(^||sample(5),-1,data)
w data
// 第三ノード(5) ★ $orderと異なる点

// $orderの第2, 3引数は、必要に応じて省略可能です
loopQuery9	;
	s gblNm = $na(^||sample("")) // 関節参照の用意「$name()」
	
	f { s gblNm = $q(@gblNm,1,data) q:gblNm=""
		
		w !,"ノード数:",$ql(gblNm)
		,", グローバル名:",$qs(gblNm,0)
		,", 第1:",$qs(gblNm,1)
		,", 第2:",$qs(gblNm,2)
		,", 第3:",$qs(gblNm,3)
		,", データ:",data		
	}
d loopQuery9

// 先ずは動作確認
w $n(^||sample(""))
// 1

w $n(^||sample(5))
// -1

// 先ずは動作確認
w $zp(^||sample(""))
// 5

w $n(^||sample(5))
// [null]

// 全てのノードとデータを^||mgにマージする
m ^||mg = ^||sample
zw ^||mg

k ^||mg
m ^||mg(1,2) = ^||sample(1,2)
zw ^||mg
// ^||mg(1,2)="第二ノード(2)"
// ^||mg(1,2,1)="第三ノード(1)"
// ^||mg(1,2,2)="第三ノード(2)"
// ^||mg(1,2,3)="第三ノード(3)"

k ^||mg
m ^||mg = ^||sample(1,2)
zw ^||mg
// ^||mg="第二ノード(2)"
// ^||mg(1)="第三ノード(1)"
// ^||mg(2)="第三ノード(2)"
// ^||mg(3)="第三ノード(3)"

s flg = 1

m:(flg) ^||true = ^||sample(1,2)
m:('flg) ^||false = ^||sample(1,2)

zw ^||true
// ^||true="第二ノード(2)"
// ^||true(1)="第三ノード(1)"
// ^||true(2)="第三ノード(2)"
// ^||true(3)="第三ノード(3)"

zw ^||false
// なし

s ^||Sample("東京都","千代田区")="https://www.city.chiyoda.lg.jp/"
s ^("中央区")="https://www.city.chuo.lg.jp/"
s ^("港区")="https://www.city.minato.tokyo.jp/"
s ^("新宿区")="https://www.city.shinjuku.lg.jp/"
s ^("新宿区","西新宿",6,10,1)="日土地西新宿ビル"
s ^(1,"15階")="インターシステムズジャパン"

zw ^||Sample
// ^||Sample("東京都","中央区")="https://www.city.chuo.lg.jp/"
// ^||Sample("東京都","千代田区")="https://www.city.chiyoda.lg.jp/"
// ^||Sample("東京都","新宿区")="https://www.city.shinjuku.lg.jp/"
// ^||Sample("東京都","新宿区","西新宿",6,10,1)="日土地西新宿ビル"
// ^||Sample("東京都","新宿区","西新宿",6,10,1,"15階")="インターシステムズジャパン"
// ^||Sample("東京都","港区")="https://www.city.minato.tokyo.jp/"

w ^||Sample("東京都","千代田区")
// https://www.city.chiyoda.lg.jp/
w ^("中央区")
// https://www.city.chuo.lg.jp/
w ^("新宿区")
// https://www.city.shinjuku.lg.jp/
w ^("新宿区","西新宿",6,10,1)
// 日土地西新宿ビル

// 一応こんなことも可能
w ^||Sample("東京都","中央区")
s key=""
f { s key=$o(^(key)) q:key=""  w !,key }
// 中央区
// 千代田区
// 新宿区
// 港区


//-------------------------------------------------
// ネイキッド・インジケータ($zreference)
w ^||Sample("東京都","中央区")
// https://www.city.chuo.lg.jp/
w $zr
// ^||Sample("東京都","中央区")

s gbl = "^||sample" // 文字列化

w @gbl@(1)
// 第一ノード(1)

// 文字列化は$name()を使用すると便利です
s gbl = $na(^||sample(1))
w gbl

// 下位ノードを求めるときは「@」を連結します。
// 例）@"^||sample(1)"@(1,2)
w @gbl@(1,2)
// 第三ノード(2)