【IRIS/Cache】SQLからCSVファイルを作成する

SQLを実行し、テーブルのレコードからCSVファイルを生成する方法をご紹介します。
※簡易版

※この記事は下記の方向けになります。

テーブルのレコードからCSVファイルを生成したい
テーブル毎に固有のクラスを作りたくない
ある程度条件を絞ってCSVとして出力したい

はじめに
CSVファイルをエクスポートする
1. 解説
  1. 関数の引数を解説
  2. 出力処理の解説
おわりに

はじめに

テーブルのレコードから、CSVファイルを作成する方法をご紹介します。

今回の方法は、SQLを利用してデータの絞り込みを行いCSVファイルの出力を行います。
また、SQLの組み方次第では、二つのテーブルをjoinしたデータを出力する事も可能なので、汎用性が高いです。

また、テーブル毎の出力関数を作成する必要がないのもメリットです。

テーブル単位での全件CSV出力に関しては、下記記事を参照してください。

【IRIS/Cache】テーブルのレコードからCSVファイルを作成する

テーブルのレコードから、CSVファイルを作成する方法をご紹介します。今回の方法は、「SQL.Export.Mgr.cls」を利用して、CSVをインポートします。全件出力するので、出力条件を定義する事が出来ませんが、レコードを簡易に出力できるので利便性は高いです。また、テーブル毎の出力関数を作成する必要がないのもメリットです。

CSVファイルをエクスポートする

SQLを使用してCSVファイルを出力するので、必要なのは「SQLを実行する」「ファイルに出力する」の２つの機能になります。

この２つの機能を元に、簡単なサンプルを2つ程作成しました。
関数の解説は後程行います。

%DisplayFormattedを使用するケース

CSV出力に必要な処理は3行のみ

ClassMethod output(fileName As %String, dlm As %String = ",", charSet As %String = "UTF8", query As %String, arg...)
{
	#dim rset as %SQL.StatementResult
	#dim messages as %SQL.Manager.Messages
	try {
		s stmt = ##class(%SQL.Statement).%New(1)
		, rset = stmt.%ExecDirect(, query, arg...)
		d rset.%DisplayFormatted("CSV", fileName, .messages, .filesUsed, charSet, dlm)
		
		w !,"◆結果：",!
		d messages.%Display()
		
		w !!,"◆ファイル名:",!
		zw filesUsed
	}catch e {
		w !,$System.Status.DisplayError(e.AsStatus())
	}
}

【コマンド実行】
s query = “select xActive,zUpdateCount,dele,storeCd,patientId,漢字氏名,カナ氏名,ローマ字氏名,漢字旧姓,カナ旧姓,性別,生年月日,死亡日時,コメント,新患登録日,ABO血液型,RH血液型,未使用区分 from developer_csv.Patient where 漢字氏名 like ? & 性別=?”
s fileName = “D:\Temp\csv\読み込み\patient_data_sample_export2” // 拡張子なし

d ##class(developer.csv.Sample).output(fileName,,, query, “%山%”, “男”)

%Printを使用するケース

ClassMethod output(fileName As %String, dlm As %String = ",", charSet As %String = "UTF8", query As %String, arg...)
{
	#dim rset as %SQL.StatementResult
	try {
		s stmt = ##class(%SQL.Statement).%New(1)
		, rset = stmt.%ExecDirect(, query, arg...)
		
		s flg = "WNS"_$s(charSet'="":"K\"_charSet_"\", 1:"")
		
		// 出力
		open fileName:(flg):5
		use fileName while rset.%Next() { d rset.%Print(dlm) }
		close fileName
	}catch e {
		w !,$System.Status.DisplayError(e.AsStatus())
	}
}

【コマンド実行】
s query = [共通]
s fileName = “D:\Temp\csv\読み込み\patient_data_sample_export2.csv“

d ##class(developer.csv.Sample).output(fileName,,, query, “%山%”, “男”)

解説

関数の引数を解説

引数名	説明
fileName	CSVファイルの出力先（ファイル名含む）　※「%DisplayFormatted」の方は、ファイルの拡張子は無し
dlm	デリミタ(初期値=”,”)
charSet	ファイルの文字コード(初期値=”UTF8″)
query	SQLのクエリ
arg	where節の「?」に対応する値「?」がなければ省略可