【IRIS/Cache】CSVファイルからレコードを生成する(別手段)

ClassMethod importCSV(fileName As %String, clsNm As %String, rowName As %String, rowType As %String = "", dlm As %String = ",", charSet As %String = "UTF8")
{
	s (makeRflg,openFlg) = 0
	try {
		s mgr = ##class(%SQL.Import.Mgr).%New()
		
		s mgr.FileName = fileName
				
		s sNm = $p(clsNm, ".", 1, *-1)
		, tNm = $p(clsNm, ".", *)
		
		s mobj = ##class(%SQL.Manager.API).%New()
		$$$ThrowOnError(mobj.CheckIdentifier(.sNm))
		$$$ThrowOnError(mobj.CheckIdentifier(.tNm))
				
		s mgr.ClassName = clsNm
		s mgr.TableName = $tr(sNm,".","_")_"."_tNm
		s mgr.IQN=$$$BuildIQN(sNm, tNm)

　　　　// CSVファイルの設定
		s mgr.Delimiter = dlm
		//s mgr.StringQuote = """"
		s mgr.Charset = charSet
		
        // 日時の設定
		s mgr.DateFormat = 10  // 10:YYYY-MM-DD, YYYY/MM/DD
		, mgr.TimeFormat = 1
		, mgr.TimeStampFormat = 8 // YYYY-MM-DD hh:mm:ss
		
        // 取り込み設定
		s mgr.NoCheck = 0      // 1:validationを行わない
		s mgr.HasHeaders = 1   // 1:ヘッダを含む(複数行ヘッダはNG)
		s mgr.DeferIndices = 0 // 1:データインポート後にインデックス作成
		
		// CSVカラムと型を設定
		f pos=1:1:$l(rowName,",") d mgr.ColumnNames.Insert($p(rowName,",",pos))
		i (rowType'="") f pos=1:1:$l(rowType,",") d mgr.ColumnTypes.Insert($p(rowType,",",pos))
		
		
		$$$ThrowOnError(mgr.GenerateImportRoutine()) // 取り込みルーチン生成
		s makeRflg = 1
		
		$$$ThrowOnError(mgr.OpenImport()) // ファイルを開く
        s openFlg = 1
		i (mgr.HasHeaders) $$$ThrowOnError(mgr.ReadHeader(.header)) // ヘッダを飛ばす
	
		s (total,rows,okCnt,ngCnt) = 0
		d {
			d mgr.ImportRows(.rows, .ok,, .done,, total)
			s total = total + rows
			, okCnt = okCnt + ok
		} while('done)
		zw ^IRIS.TempSQLImp($job)
		
		w !!,$$$FormatText("総数:%1, 成功:%2, 失敗:%3 at %4", total, okCnt, mgr.ErrorCount(), $zdt($h,3,1))
		
		$$$ThrowOnError(mgr.BuildIndices())

        // 後処理
		$$$ThrowOnError(mgr.CloseImport())
        s openFlg = 0
		$$$ThrowOnError(mgr.DeleteImportRoutine()) // 取り込みルーチン削除
	}catch e {
		w !,$System.Status.DisplayError(e.AsStatus())
		
		d:(openFlg) mgr.CloseImport() // ファイルを閉じる
		d:(makeRflg) mgr.DeleteImportRoutine() // ルーチン削除
	}
}

s mgr = ##class(%SQL.Import.Mgr).%New()

s mgr.ClassName = clsNm // データクラス名
s mgr.TableName = $tr(sNm,".","_")_"."_tNm // SQLで使用するクラス名
s mgr.IQN=$$$BuildIQN(sNm, tNm) // 内部用

s mgr.Delimiter = dlm // デリミタ "," or $c(9)
s mgr.StringQuote = """" // 値を括っている文字　"123","455"の「"」等
s mgr.Charset = charSet // 文字コード

s mgr.DateFormat = 10  // 10:YYYY-MM-DD, YYYY/MM/DD
, mgr.TimeFormat = 1
, mgr.TimeStampFormat = 8

s mgr.NoCheck = 0      // 1:validationを行わない
s mgr.HasHeaders = 1   // 1:ヘッダを含む(複数行ヘッダはNG)
s mgr.DeferIndices = 0 // 1:データインポート後にインデックス作成

f pos=1:1:$l(rowName,",") d mgr.ColumnNames.Insert($p(rowName,",",pos))
i (rowType'="") f pos=1:1:$l(rowType,",") d mgr.ColumnTypes.Insert($p(rowType,",",pos))

s (total,rows,okCnt,ngCnt) = 0
d {
	d mgr.ImportRows(.rows, .ok,, .done,, total)
	s total = total + rows
	, okCnt = okCnt + ok
} while('done)
zw ^IRIS.TempSQLImp($job)

&sql(INSERT INTO "developer_csv".Patient (xActive,zUpdateCount,dele,storeCd,patientId,漢字氏名,カナ氏名,ローマ字氏名,漢字旧姓,カナ旧姓,性別,生年月日,死亡日時,コメント,新患登録日,ABO血液型,RH血液型,未使用区分)
    VALUES (:valray(1),:valray(2),:valray(3),:valray(4),:valray(5),:valray(6),:valray(7),:valray(8),:valray(9),:valray(10),:valray(11),:valray(12),:valray(13),:valray(14),:valray(15),:valray(16),:valray(17),:valray(18)))